下面就是Flash了
Flash中:
打开Flash,新建一个Flash文档,大小200*230,命名 xml-008.fla ;
新建一个图层,命名为:Actions
--------------------------------------------------
新建一个影片剪辑,命名为:btn_over ;此影片剪辑用来装饰鼠标滑过时的效果.
新建二个图层.分别命名为:
--------------------------------------------------
Actions
cont
--------------------------------------------------
在图层cont的第一帧画一个200*18,没有边框的矩形,填充颜色为#0099FF;透明度为0,x,y值为0,
在第三帧按[F6],选中该帧的矩形,将透明度调为50;再选中第一帧,打开属性面板,在补间那选形状.
在图层Actions的第三帧按[F6],在该帧输入代码: stop();
完成如图:
回到主场景,新建一个按钮.命名为:btn ;
在'指针经过','按下'帧按[F6].
将库中的 btn_over 影片剪辑拉到'指针经过'帧,x,y值为0,
再在'按下'帧画一个200*18,没有边框的矩形,填充颜色为#FFF3CC; 透明度为50, x,y值为0,
回到主场景,新建一个影片剪辑.命名为:columnItem,
在高级选项那 标识符为:columnItem,在勾选上 '为ActionScript导出','第一帧导出'.
新建三个图层,分别命名为:
--------------------------------------------------
btn
text
line
--------------------------------------------------
在图层line的第一帧画一条100*1的虚线.填充颜色为#660000; 透明度为80 ; x值为0,y值为18;
在图层text画一个动态文本框,大小为200*18; 文本颜色为:#660000; x,y值为0, 实例名为: cName ;
在图层btn中,将btn按钮元件拉到第一帧.x,y值为0,实例名为: btn ;
完成如图:
回到主场景.
打开组件面板,拉一个Accordion组件到库中;
在Actions图层的第一帧输入下面的代码:
//导入类.
import mx.core.View;
import mx.containers.Accordion;
//===========================================
//使用系统编码.防止乱码.
System.useCodepage = true;
//隐藏按钮的鼠标手形.
Button.prototype.useHandCursor = false;
//===========================================
//实例化一个xml对象.
var columnData:XML = new XML();
//分析时忽略xml文档中的空格.
columnData.ignoreWhite = true;
//加载http://localhost/xml/xml-008.asp.
columnData.load("http://localhost/xml/xml-008.asp?ran="+Math.random(9999));
//调用XML.onLoad事件.
columnData.onLoad = function(success:Boolean)
{
//如果加载成功,success=true;否则success=false;
if (success) {
//执行dragColumn函数.
dragColumn(columnData.firstChild.childNodes);
}
};
//==========dragColumn函数用来绘制专栏数据===========
function dragColumn(column_arr:Array):Void
{
//创建Accordion组件的实例.
//createClassObject(类名称,"实例名",深度,{初始对象});
createClassObject(Accordion, "column", 0, {_x:0, _y:0, _width:200, _height:240});
//执行columnStyle函数.
columnStyle();
//获取数组的长度.
var columnLen:Number = column_arr.length;
//专栏的子菜单数组.
var columnChild:Array;
//引用专题栏目的对象.
var MainItem:Object;
//循环创建专题栏目.
for (var i = 0; i<columnLen; i++) {
//创建专题栏目.MainItem引用新创建的对象.
//createSegment(类名称,值或实例名称,显示的标题);
MainItem = column.createSegment(View, i, column_arr[i].attributes.name);
//获取专栏的子菜单数组.
columnChild = column_arr[i].childNodes;
//循环创建专题栏目的子菜单.
for (var j = 0; j<columnChild.length; j++) {
//使用with语句简写代码.
//创建专题栏目的子菜单.
//createChild("库中的链接名","实例名称",{初始对象});
//18.5是columnItem影片剪辑的高度和行距.
with (MainItem.createChild("columnItem", "columnItem", {_x:0, _y:18.5*j})) {
//显示子菜单.
cName.text = columnChild[j].attributes.name;
//获取点击的URL;
btn.cURL = columnChild[j].attributes.url;
//btn.onRelease事件.
btn.onRelease = btnEvent;
}
}
}
}
//========执行btn.onRelease事件的函数=========
function btnEvent():Void
{
//连接点击的URL.
getURL(this.cURL, "_blank");
}
//=======columnStyle函数设置专栏的样式=========
function columnStyle():Void
{
//文本颜色.
column.setStyle("color", 0x660000);
//字体.
column.setStyle("fontFamily", "隶书");
//主题.
column.setStyle("themeColor", "haloOrange");
//点击专栏的动画.
column.setStyle("openEasing", mx.transitions.easing.Bounce.easeOut);
}
现在大家就可以测试影片了.
