GLOBAL.ASA:
<object runat="server" scope="session" id="MyAd" progid="MSWC.AdRotator"> </object>
You could reference the object "MyAd" from any page in the ASP application:
某个.ASP文件:
<%=MyAd.GetAdvertisement("/banners/adrot.txt")%>
TypeLibrary（类型库）是一个容器，其中装有对应于COM对象的DLL文件的目录。通过在Global.asa对TypeLibrary的调用进行引用，可以访问COM对象的常量，同时ASP代码也能更好地报告错误。假如您的站点的应用程序依赖于已在类型库中声明过数据类型的COM对象，您可以在Global.asa中对类型库进行声明。
<!--METADATA TYPE="TypeLib" file="filename" uuid="typelibraryuuid" version="versionnumber" lcid="localeid" -->
| 参数 | 描述 |
|---|---|
| file | 规定指向类型库的绝对路径。参数file或者uuid，两者缺一不可。 |
| uuid | 规定了针对类型库的唯一的标识符。参数file或者uuid，两者缺一不可。 |
| version | 可选。用于选择版本。假如没有找到指定的版本，将使用最接近的版本。 |
| lcid | 可选。Optional. 用于类型库的地区标识符。 |
服务器会返回以下的错误消息之一：
| 错误 | 代码 | 描述 |
|---|---|---|
| ASP | 0222 | Invalid type library specification |
| ASP | 0223 | Type library not found |
| ASP | 0224 | Type library cannot be loaded |
| ASP | 0225 | Type library cannot be wrapped |
注释：METADATA标签可位于Global.asa文件中的任何位置（在<script>标签的内外均可）。不过，我们还是推荐将METADATA标签放置于Global.asa文件的顶部。
关于可以在Global.asa文件中引用的内容的限定：
你无法显示Global.asa文件中的文本。此文件无法显示信息。
你只能在Application_OnStart和Application_OnEnd子例程中使用Server和Application对象。在Session_OnEnd子例程中，你可以使用Server、Application和Session对象。在Session_OnStart子例程中，你可使用任何内建的对象。
Global.asa常用于对变量进行初始化。
下面的例子展示如何检测某位访问者首次到达站点的确切时间。时间存储在名为"started"的Session对象中，并且"started"变量的值可被应用程序中的任何ASP页面访问：
<script language="vbscript" runat="server">
sub Session_OnStart
Session("started")=now()
end sub
</script>
Global.asa也可用于控制页面访问。
下面的例子展示如何把每位新的访问者重定向到另一个页面，在这个例子中会定向到"newpage.asp"这个页面：
<script language="vbscript" runat="server">
sub Session_OnStart
Response.Redirect("newpage.asp")
end sub
</script>
我们还可以在Global.asa中引用函数。
在下面的例子中，当Web服务器启动时，Application_OnStart子例程也会启动。随后，Application_OnStart子例程会调用另一个名为"getcustomers"的子例程。"getcustomers"子例程会打开一个数据库，然后从"customers"表中取回一个记录集。此记录集会赋值给一个数组，在不查询数据库的情况下，这个数组可被任意的ASP页面访问：
<script language="vbscript" runat="server">
sub Application_OnStart
getcustomers
end sub
sub getcustomers
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs=conn.execute("select name from customers")
Application("customers")=rs.GetRows
rs.Close
conn.Close
end sub
</script>
在这个例子中，我们要创建一个可计算当前访客的Global.asa文件。
Application_OnStart设置当服务器启动时，Application变量"visitors"的值为0。
每当有新用户访问时，Session_OnStart子例程就会给变量"visitors"加1。
每当Session_OnEnd子例程被触发时，此子例程就会从变量"visitors"减1。
Global.asa文件：
<script language="vbscript" runat="server">
Sub Application_OnStart
Application("visitors")=0
End Sub
Sub Session_OnStart
Application.Lock
Application("visitors")=Application("visitors")+1
Application.UnLock
End Sub
Sub Session_OnEnd
Application.Lock
Application("visitors")=Application("visitors")-1
Application.UnLock
End Sub
</script>
此ASP文件会显示当前用户的数目：
<html>
<head>
</head>
<body>
<p>
There are <%response.write(Application("visitors"))%>
online now!
</p>
</body>
</html>
